易语言实现http下载断点续传功能的代码

DLL命令表

成都创新互联公司专注于企业营销型网站、网站重做改版、建湖网站定制设计、自适应品牌网站建设、H5场景定制、成都商城网站开发、集团公司官网建设、外贸网站建设、高端网站制作、响应式网页设计等建站业务，价格优惠性价比高，为建湖等各大城市提供网站开发制作服务。

.版本 2
.DLL命令 InternetGetConnectedState, , "Wininet.dll", "InternetGetConnectedState"
  .参数 lpdwFlags, 整数型, 传址
  .参数 dwReserved, 整数型
.DLL命令 InternetOpenA, 整数型, "Wininet.dll", "InternetOpenA"
  .参数 lpszAgent, 文本型
  .参数 dwAccessType, 整数型
  .参数 lpszProxyName, 整数型
  .参数 lpszProxyBypass, 整数型
  .参数 dwFlags, 整数型
.DLL命令 InternetOpenUrlA, 整数型, "Wininet.dll", "InternetOpenUrlA"
  .参数 hInternet, 整数型
  .参数 lpszUrl, 文本型
  .参数 lpszHeaders, 文本型
  .参数 dwHeadersLength, 整数型
  .参数 dwFlags, 整数型
  .参数 dwContext, 整数型
.DLL命令 HttpQueryInfoA, 整数型, "Wininet.dll", "HttpQueryInfoA"
  .参数 hRequest, 整数型
  .参数 dwInfoLevel, 整数型
  .参数 lpvBuffer, 整数型, 传址
  .参数 lpdwBufferLength, 整数型, 传址
  .参数 lpdwIndex, 整数型, 传址
.DLL命令 InternetCloseHandle, , "Wininet.dll", "InternetCloseHandle"
  .参数 handle, 整数型
.DLL命令 InternetReadFile, 整数型, "Wininet.dll", "InternetReadFile"
  .参数 hFile, 整数型
  .参数 lpBuffer, 字节集
  .参数 dwNumberOfBytesToRead, 整数型
  .参数 lpdwNumberOfBytesRead, 整数型, 传址
.DLL命令 CallWindowProcA, 整数型, , "CallWindowProcA"
  .参数 子程序指针, 子程序指针
  .参数 参数1, 整数型
  .参数 参数2, 整数型
  .参数 参数3, 整数型
  .参数 参数4, 整数型

HTTP

.版本 2
.支持库 spec
.支持库 iconv
.程序集 HTTP, , 公开
.程序集变量 file_hwnd, 整数型
.程序集变量 dwBytes, 长整数型
.程序集变量 url, 文本型
.程序集变量 dwByteToRead, 长整数型
.程序集变量 是否_开始下载, 逻辑型
.程序集变量 是否_停止, 逻辑型
.程序集变量 file_name, 文本型
.程序集变量 file_type, 文本型
.程序集变量 file_path, 文本型
.程序集变量 start_time, 长整数型
.程序集变量 speed, 长整数型
.子程序 _初始化, , , 当基于本类的对象被创建后，此方法会被自动调用
.子程序 _销毁, , , 当基于本类的对象被销毁前，此方法会被自动调用
停止下载 ()
.子程序 创建下载, 逻辑型, 公开
.参数 远程地址, 文本型
.参数 本地地址, 文本型, 可空
.局部变量 url_code, 文本型
.局部变量 url_name, 文本型
.如果真 (取文本左边 (远程地址, 7) ≠ “http://”)
  .如果真 (取文本左边 (远程地址, 8) ≠ “https://”)
    返回 (假)
  .如果真结束
.如果真结束
file_name ＝ 取文本右边 (远程地址, 取文本长度 (远程地址) － 倒找文本 (远程地址, “/”, , 假))
file_type ＝ 取文本右边 (远程地址, 取文本长度 (远程地址) － 倒找文本 (远程地址, “.”, , 假) ＋ 1)
url_code ＝ 取文本右边 (远程地址, 取文本长度 (远程地址) － 寻找文本 (远程地址, “/”, 8, 假))
url_name ＝ 取文本左边 (远程地址, 寻找文本 (远程地址, “/”, 8, 假))
url ＝ url_name ＋ UTF8_URL_编码 (url_code) ' 支持中文名
.如果真 (是否为空 (本地地址))
  本地地址 ＝ 取运行目录 () ＋ “\” ＋ file_name
.如果真结束
.如果 (文件是否存在 (本地地址))
  file_hwnd ＝ 打开文件 (本地地址, #改写, )
.否则
  file_hwnd ＝ 打开文件 (本地地址, #重写, )
.如果结束
.如果真 (file_hwnd ＝ 0)
  返回 (假)
.如果真结束
移到文件尾 (file_hwnd)
dwBytes ＝ 取文件长度 (file_hwnd)
file_path ＝ 本地地址
返回 (真)
.子程序 开始下载, 逻辑型, 公开
.参数 进度回调, 整数型
.参数 退出回调, 整数型
.局部变量 dwFlags, 整数型
.局部变量 strAgent, 文本型
.局部变量 hOpen, 整数型
.局部变量 szHead, 文本型
.局部变量 szTemp, 字节集
.局部变量 hConnect, 整数型
.局部变量 dwSize, 长整数型
是否_开始下载 ＝ 真
是否_停止 ＝ 假
InternetGetConnectedState (dwFlags, 0)
strAgent ＝ “Agent” ＋ 到文本 (取启动时间 ())
.如果 (位与 (dwFlags, 4) ＝ 0)
  hOpen ＝ InternetOpenA (strAgent, 4, 0, 0, 0)
.否则
  hOpen ＝ InternetOpenA (strAgent, 0, 0, 0, 0)
.如果结束
.如果真 (hOpen ＝ 0)
  返回 (假)
.如果真结束
szHead ＝ “Accept: */*” ＋ #换行符 ＋ “Accept-Language: zh-cn” ＋ #换行符 ＋ “Accept-Encoding: no-gzip, deflate” ＋ #换行符 ＋ “User-Agent: Mozilla/4.0(compatible; MSIE 6.0; Windows NT 5.0; MyIE2; .NET CLR 1.1.4322)”
szHead ＝ szHead ＋ #换行符 ＋ “Range:bytes=” ＋ 到文本 (dwBytes) ＋ “-”
szTemp ＝ 取空白字节集 (10240)
hConnect ＝ InternetOpenUrlA (hOpen, url, szHead, 取文本长度 (szHead), 2214592768, 0)
dwByteToRead ＝ 0
.如果真 (HttpQueryInfoA (hConnect, 536870917, dwByteToRead, 4, 0) ＝ 0)
  dwByteToRead ＝ 0
.如果真结束
dwByteToRead ＝ dwByteToRead ＋ dwBytes
start_time ＝ time ()
.循环判断首 ()
  .如果真 (是否_停止 ＝ 真)
    调用子程序 (退出回调, , , )
    返回 (假)
    跳出循环 ()
  .如果真结束
  .如果真 (InternetReadFile (hConnect, szTemp, 10240, dwSize) ＝ 0)
    关闭文件 (file_hwnd)
    返回 (假)
  .如果真结束
  .如果 (dwSize ＝ 0)
    跳出循环 ()
  .否则
    szTemp ＝ 取字节集左边 (szTemp, dwSize)
    写出字节集 (file_hwnd, szTemp)
  .如果结束
  dwBytes ＝ dwBytes ＋ dwSize
  调用子程序 (进度回调, , , )
.循环判断尾 (真)
关闭文件 (file_hwnd)
是否_开始下载 ＝ 假
InternetCloseHandle (hOpen)
返回 (真)
.子程序 取已下载尺寸, 长整数型, 公开
返回 (dwBytes)
.子程序 取总大小, 长整数型, 公开
返回 (dwByteToRead)
.子程序 取文件名, 文本型, 公开
返回 (file_name)
.子程序 取扩展类型, 文本型, 公开
返回 (file_type)
.子程序 取下载进度, 整数型, 公开
返回 (dwBytes × 100 ÷ dwByteToRead)
.子程序 取下载时长, 整数型, 公开
返回 (time () － start_time)
.子程序 取本地文件名, 文本型, 公开
返回 (file_path)
.子程序 停止下载, , 公开
是否_停止 ＝ 真
.如果真 (file_hwnd ≠ 0)
  关闭文件 (file_hwnd)
.如果真结束
.子程序 是否开始下载, 逻辑型, 公开
返回 (是否_开始下载)
.子程序 UTF8_URL_编码, 文本型
.参数 url, 文本型
.局部变量 字节集数据, 字节集
.局部变量 i, 整数型
.局部变量 b, 文本型
.局部变量 a, 文本型
字节集数据 ＝ 编码转换 (到字节集 (url), #编码_GBK, #编码_UTF_8, )
.计次循环首 (取字节集长度 (字节集数据), i)
  a ＝ 取十六进制文本 (字节集数据 [i])
  b ＝ b ＋ “%” ＋ a
.计次循环尾 ()
返回 (b)
.子程序 time, 长整数型
.局部变量 初始时间, 日期时间型
初始时间 ＝ 到时间 (“1970-01-01 08:00:00”)
返回 (取时间间隔 (取现行时间 (), 初始时间, #秒))
.子程序 date, 日期时间型
.参数 时间戳记值, 长整数型, , 要转换的时间戳记值
.局部变量 初始时间, 日期时间型
初始时间 ＝ 到时间 (“1970-01-01 08:00:00”)
返回 (增减时间 (初始时间, #秒, 时间戳记值))

http下载断点续传

.版本 2
.程序集 窗口程序集_启动窗口
.程序集变量 下载, HTTP
.程序集变量 上次位置, 整数型
.程序集变量 是否结束, 逻辑型
.子程序 __启动窗口_创建完毕
是否结束 ＝ 假
.子程序 _下载按钮_被单击
进度条1.位置 ＝ 0
.如果真 (下载.创建下载 (“http://gw.datiw.com:8080/201708/tools/eyy_chs_jb51.rar”) ＝ 假)
  信息框 (“创建任务失败!”, 0, )
.如果真结束
.如果真 (下载.开始下载 (到整数 (&下载回调), 到整数 (&退出回调)))
  进度条1.位置 ＝ 100
  信息框 (“下载完成!”, 0, )
.如果真结束
.子程序 下载回调
进度条1.位置 ＝ 下载.取下载进度 ()
处理事件 () ' 必须加，否则假死
.子程序 退出回调
.如果真 (是否结束 ＝ 真)
  结束 ()
.如果真结束
.子程序 _停止按钮_被单击
下载.停止下载 ()
.子程序 _时钟1_周期事件
.如果真 (下载.是否开始下载 ())
  标签1.标题 ＝ “当前任务总大小：” ＋ 到文本 (到整数 (下载.取总大小 () ÷ 1024)) ＋ “ KB”
  标签2.标题 ＝ “当前已下载：” ＋ 到文本 (到整数 (下载.取已下载尺寸 () ÷ 1024)) ＋ “ KB”
  标签3.标题 ＝ “当前下载速度：” ＋ 到文本 (到整数 ((下载.取已下载尺寸 () － 上次位置) ÷ 1024)) ＋ “ KB/s”
  标签4.标题 ＝ “当前下载进度：” ＋ 到文本 (下载.取下载进度 ()) ＋ “ %”
  标签5.标题 ＝ “保存文件路径：” ＋ 到文本 (下载.取本地文件名 ())
  上次位置 ＝ 下载.取已下载尺寸 ()
.如果真结束
.子程序 __启动窗口_可否被关闭, 逻辑型
.如果真 (下载.是否开始下载 () ＝ 假)
  返回 (真)
.如果真结束
下载.停止下载 ()
是否结束 ＝ 真 ' 保证退出循环
返回 (假)

运行结果：

易语言实现http下载断点续传功能的代码

总结

以上就是这篇文章的全部内容了，希望本文的内容对大家的学习或者工作具有一定的参考学习价值，谢谢大家对创新互联的支持。如果你想了解更多相关内容请查看下面相关链接

文章题目：易语言实现http下载断点续传功能的代码
当前网址：http://ybzwz.com/article/poegdi.html

易语言实现http下载断点续传功能的代码

其他资讯