宜宾网站建设公司

UnityShader如何实现纹理遮罩效果

这篇文章主要为大家展示了Unity Shader如何实现纹理遮罩效果，内容简而易懂，希望大家可以学习一下，学习完之后肯定会有收获的，下面让小编带大家一起来看看吧。

我们提供的服务有：网站设计、网站制作、微信公众号开发、网站优化、网站认证、平罗ssl等。为超过千家企事业单位解决了网站和推广的问题。提供周到的售前咨询和贴心的售后服务，是有科学管理、有技术的平罗网站制作公司

纹理遮罩用处很多，简单来讲就是允许我们可以保护模型中的某些区域不受某些因素的影响。例如我们有时希望模型表面某些区域的反光强烈一些，而某些区域弱一些。为了得到更加细腻的结果，我们需要用一张遮罩纹理来控制该光照。还有一些情况就是某些模型需要多张纹理混合时，此时使用遮罩纹理可以控制如何混合这些纹理。

具体流程为：通过采样得到遮罩纹理的纹素值，然后使用其中某个或者几个通道的值来与某种表面属性进行相乘。当该通道的值为0时，此时该表面属性不受遮罩纹理的影响。

shader代码如下：

Shader "Custom/MaskTexture"
{
  Properties
  {
    _Color ("Color", Color) = (1,1,1,1)
    _MainTex ("Main Tex", 2D) = "white" {}
 _BumpMap("Normal Map", 2D) = "white" {}
 _BumpScale("Bump Scale", Float) = 1.0
 _SpecularMask("Specular Mask", 2D) = "white" {}
 _SpecularScale("Specular Scale", Float) = 1.0
 _Specular("Specular", Color) = (1,1,1,1)
 _Gloss("Gloss", Range(8.0, 256)) = 20
 }
 
 SubShader
 {
 Pass
 {
  Tags{"LightMode" = "ForwardBase"}
 
  CGPROGRAM
 
  #pragma vertex vert
  #pragma fragment frag
  #include "UnityCG.cginc"
  #include "Lighting.cginc"
 
  fixed4 _Color;
  sampler2D _MainTex;
  float4 _MainTex_ST;   //纹理变量名+_ST为unity内置宏，存储了该纹理的缩放大小和偏移量，分别对应.xy和.zw属性
  sampler2D _BumpMap;
  float _BumpScale;    //控制凹凸程度的变量
  sampler2D _SpecularMask; //遮罩纹理
  float _SpecularScale;  //控制遮罩纹理的可见度
  fixed4 _Specular;
  float _Gloss;
 
  struct a2v {
  float4 vertex : POSITION;
  float3 normal : NORMAL;
  float4 tangent : TANGENT;
  float4 texcoord : TEXCOORD0;
  };
 
  struct v2f {
  float4 pos : SV_POSITION;
  float2 uv : TEXCOORD0;
  float3 lightDir : TEXCOORD1;
  float3 viewDir : TEXCOORD2;
  };
 
  v2f vert(a2v v)
  {
  v2f o;
 
  o.pos = UnityObjectToClipPos(v.vertex);
  //将_MainTex纹理信息(缩放大小和偏移量以及坐标信息)存储到o.uv.xy中
  o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
 
  //unity内置宏，计算并得到从模型空间到切线空间的变换矩阵rotation
  TANGENT_SPACE_ROTATION;
  //获取切线空间下的光照方向
  o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
  //获取切线空间下的视角方向
  o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;;
 
  return o;
  }
 
  fixed4 frag(v2f i) : SV_Target
  {
  //将切线空间下的光照方向和视角方向单位化
  fixed3 tangentLightDir = normalize(i.lightDir);
  fixed3 tangentViewDir = normalize(i.viewDir);
 
  //获取切线空间下的法向量
  fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uv));
  tangentNormal.xy *= _BumpScale;
  tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
 
  //获取片元上的主纹理，并和变量_Color相乘得到其混合结果
  fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
  //获取环境光
  fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
  //漫反射计算
  fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
 
  //高光反射计算，其计算方式跟前文的计算一样，这里只能另外跟specularMask的遮罩纹理相乘得到其与遮罩纹理的混合结果
  fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
  fixed specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;
  fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss) * specularMask;
 
  return fixed4(ambient + diffuse + specular, 1.0);
  }
 
  ENDCG
 }
  }
  FallBack "Specular"
}

以上就是关于Unity Shader如何实现纹理遮罩效果的内容，如果你们有学习到知识或者技能，可以把它分享出去让更多的人看到。


当前名称：UnityShader如何实现纹理遮罩效果
标题路径：http://ybzwz.com/article/poccis.html

其他资讯